Christopher G. Lewis - Scripting Blog

Dealing with CScript and Wscript (How to restart a Wscript in Cscript)

2004-05-26T16:57:00.000-05:00

I just had a question regarding the IsCScript function - which ends a script if it's not run in CScript. How do you deal with this the very first time if you are in a login script. The simple answer is to fix CScript, and restart the script:

'----------------------------------------+----------------------------------------
' Login.vbs - Default login script for OU=Local 
'
'  Copyright© 2004, Christopher G. Lewis - HTTP://www.ChristopherLewis.com
'
' Date   Name    Comment
' ------ ------- -----------------------------------------------------------------
' 030507 CGL     Created
'----------------------------------------+----------------------------------------
Option Explicit

Dim objFSO
Dim WshShell
Dim WshNetwork

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set WshShell  = WScript.CreateObject ("WScript.shell")
Set WshNetwork = WScript.CreateObject("WScript.Network")

'Check for CScript
If Not IsCScript() Then
  SetCScript()
  RestartWithCScript()
  Wscript.Quit 0
End If

Call Main()

'Clean up
Set objFSO = Nothing
Set WshShell  = Nothing
Set WshNetwork = Nothing

'----------------------------------------+----------------------------------------
' Main - Main sub
'
' Date   Name    Comment
' ------ ------- -----------------------------------------------------------------
' 030508 CGL     Created
'----------------------------------------+----------------------------------------
Sub Main()
  Wscript.echo "Do Stuff"
End Sub

'----------------------------------------+----------------------------------------
' IsCscript - Checks CScript vs. WScript
'
' Date   Name    Comment
' ------ ------- -----------------------------------------------------------------
' 020507 CGL     Created
'----------------------------------------+----------------------------------------
Function IsCScript()
  Dim objRegExp
  Set objRegExp = New RegExp
  objRegExp.IgnoreCase  = true
  objRegExp.Pattern = "cscript.exe$"
  IsCScript = objRegExp.Test(WScript.FullName)
  Set objRegExp = Nothing
End Function

'----------------------------------------+----------------------------------------
' SetCScript - Sets Cscript as the startup script
'
' Date   Name    Comment
' ------ ------- -----------------------------------------------------------------
' 040526 CGL     Created
'----------------------------------------+----------------------------------------
Function SetCScript()
  WshShell.Run "Cscript //H:CScript //S", 7, true
End Function

'----------------------------------------+----------------------------------------
' RestartWithCScript - Restarts this script with cscript.  
'   Note that this doesn't deal with script arguments.  I imagine you could 
'   do something using the following:
'   Dim strCMD
'   Dim iCount
'   strCMD = "Cscript //H:CScript " & chr(34) & Wscript.ScriptFullName & CHr(34)
'   if Wscript.Arguments.Count > 0 Then
'     For iCount = 0 to Wscript.Arguments.Count-1
'       'Add Argument
'       strCMD = strCMD & " " & Wscript.Arguments(iCount)
'     Next
'   End if 
'   WshShell.Run strCMD, 1, False
'
' Date   Name    Comment
' ------ ------- -----------------------------------------------------------------
' 040526 CGL     Created
'----------------------------------------+----------------------------------------
Function RestartWithCScript()
  WshShell.Run "Cscript //H:CScript " & chr(34) & Wscript.ScriptFullName & CHr(34), 1, False
End Function

'----------------------------------------+----------------------------------------
' End of Logon.vbs
'----------------------------------------+----------------------------------------

Remove a computer from a domain

2004-03-01T10:44:00.000-06:00

Here's a function to remove a computer from a domain. We're using it as part of a massive clean up effort.

'----------------------------------------+----------------------------------------
' RemoveComputer - Removes a computer from a domain
'
' Date   Name    Comment
' ------ ------- -----------------------------------------------------------------
' 040227 CGL     Created
'----------------------------------------+----------------------------------------
Function RemoveComputer( strDomain, strComputer )
  Dim objDC
  On error resume next
  Set objDC = getobject("WinNT://" & strDomain )
  objDC.Delete "Computer", strComputer
  if err = 0 Then
    RemoveComputer = true
  else
    RemoveComputer = false
  end if
  On error goto 0
End function

Even Better Ping in C#

2003-10-24T11:58:00.000-05:00

Alright, the flash of the shell window bothered me even more than I thought.

Diving into the .Net Framework uncovered the System.Diagnostics.Process class. The Process class can use a ProcessStartInfo class which has a RedirectStandardOutput property that returns a StreamReader, which is excactly what I was looking for.

Here's the updated CSharp class. Note that there's no error handling, (probably need a try block around the objProc.Start method):

//----------------------------------------+----------------------------------------
// TCPIPServices - Namespace for TCPIP functions
//
// Date   Name    Comment
// ------ ------- -----------------------------------------------------------------
// 031021 CGL     Created
//----------------------------------------+----------------------------------------
using System;
using System.IO;
using System.Diagnostics;
using System.Text.RegularExpressions;

namespace TCPIPServices
{
  /// <summary>
  /// CTCPIPServices - Class of TCP/IP Services
  /// </summary>
  /// <remarks>
  /// TODO: NSLookup, NetStat, etc
  /// </remarks>
  public class CTCPIPServices
  {
    /// <summary>
    /// The class constructor. 
    /// </summary>
    public CTCPIPServices()
    {
    }

    /// <summary>
    /// Ping using Ping.EXE
    /// </summary>
    /// <param name="HostName">Host to Ping</param>
    /// <remarks>
    /// Creates a new procsses to execute the PING.EXE command and capture output, which
    /// is then parsed to determine results.
    /// </remarks>
    /// <returns>
    /// Returns true if ping succeeded, false if ping fails.
    /// </returns>
    public bool Ping(string HostName) 
    {
      Process objProc = new Process();
      string strCommand = "PING.EXE ";
      string strLine;
      Regex  objRegExp;

      objProc.StartInfo.FileName = strCommand;
      objProc.StartInfo.Arguments = HostName;
      objProc.StartInfo.UseShellExecute = false;
      objProc.StartInfo.RedirectStandardOutput = true;
      //objProc.StartInfo.WindowStyle = ProcessWindowStyle.Hidden;
      objProc.StartInfo.CreateNoWindow = true;
      objProc.Start();
      objProc.WaitForExit();

      //Read the output from the command
      while (objProc.StandardOutput.Peek() >= 0) 
      {
        strLine = objProc.StandardOutput.ReadLine();
        strLine = strLine.Trim();
        
        //test for Unknown Host
        objRegExp = new Regex("^Unknown", RegexOptions.IgnoreCase);
        if (objRegExp.IsMatch(strLine))
        {
          return false;
        }
        
        //DNS Succeeded, but box off-line
        objRegExp = new Regex("100% loss", RegexOptions.IgnoreCase);
        if (objRegExp.IsMatch(strLine))
        {
          return false;
        }

        //Got a reply
        objRegExp = new Regex("^Reply from", RegexOptions.IgnoreCase);
        if (objRegExp.IsMatch(strLine))
        {
          //Check for "Destination host unreachable."
          objRegExp = new Regex("Destination host unreachable", RegexOptions.IgnoreCase);
          if (objRegExp.IsMatch(strLine))
          {
            return false;
          } 
          else 
          {
            return true;
          }
        }
      }
      //Should never get here...
      return false;
    }
  }
}

Simple Ping in VBScript & C#

2003-10-21T16:24:00.000-05:00

As you might have seen from my web site, I've played with the System.Net namespace to create an ICMP version of ping in C#. Interesting in it's own right, but it's a lot of low level code.

I started looking for a simpler way to ping and return a result.

WMI supports a ping class, but only in XP and above.

With VBScript, you can use the WshShell.Exec command to exec Ping.EXE and parse the result as follows (variations of this are readily available in Google Groups):

'----------------------------------------+----------------------------------------
' Ping - Pings a host via Shell, and parses the results
'
' Date   Name    Comment
' ------ ------- -----------------------------------------------------------------
' 030620 CGL     Created
'----------------------------------------+----------------------------------------
Function Ping(strHost)
  Dim objShell
  Dim objStdOut
  Dim strLine
  Dim objRegExp
  Dim strPattern

  Ping = False

  Set objShell = WshShell.Exec("PING.EXE " & strHost)  'The command line
  Set objStdOut = objShell.StdOut 'Reads the output from the command
  Set objRegExp = New RegExp
  objRegExp.IgnoreCase = True

  Do While Not objStdOut.AtEndOfStream
    strLine = objStdOut.ReadLine
    strLine = Trim(strLine)
    'Test for "Unknown Host" - DNS Failed
    objRegExp.Pattern = "^Unknown"
    If objRegExp.Test(strLine) Then
      Ping = False
      Exit Function
    End If

    'DNS Succeeded, but box off-line
    objRegExp.Pattern = "100% loss"
    If objRegExp.Test(strLine) Then
      Ping = False
      Exit Function
    End If

    'Got a Reply From,
    objRegExp.Pattern = "^Reply from"
    If objRegExp.Test(strLine) Then
      'Check for "Destination host unreachable."
      objRegExp.Pattern = "Destination host unreachable\."
      If objRegExp.Test(strLine) Then
        Ping = False
      Else
        'S/B OK here
        Ping = True
      End If
      Exit Function
    End If
  Loop

  Set objShell = Nothing
  Set objStdOut = Nothing
  Set objRegExp = Nothing
End Function

Duplicating the key points of this code in CSharp results in the following:

//----------------------------------------+----------------------------------------
// TCPIPServices - Namespace for TCPIP functions
//
// Date   Name    Comment
// ------ ------- -----------------------------------------------------------------
// 031021 CGL     Created
//----------------------------------------+----------------------------------------
using System;
using System.Text.RegularExpressions;

//Reference to: Windows Script Host Object Model
using IWshRuntimeLibrary;

namespace TCPIPServices
{
  /// <summary>
  /// CTCPIPServices - Class of TCP/IP Services
  /// </summary>
  /// <remarks>
  /// TODO: NSLookup, NetStat, etc
  /// </remarks>
  public class CTCPIPServices
  {
    /// <summary>
    /// The class constructor. 
    /// </summary>
    public CTCPIPServices()
    {
    }

    /// <summary>
    /// Ping using Ping.EXE
    /// </summary>
    /// <param name="HostName">Host to Ping</param>
    /// <remarks>
    /// Uses WSH 5.6 to exec the PING.EXE command and capture output, which
    /// is then parsed to determine results
    /// </remarks>
    /// <returns>
    /// Returns true if ping succeeded, false if ping fails.
    /// </returns>
    public bool Ping(string HostName) 
    {
      IWshRuntimeLibrary.WshShell     objShell = new IWshRuntimeLibrary.WshShell();
      IWshRuntimeLibrary.TextStream   tsStdOut;
      string                          strCommand = "PING.EXE " + HostName;
      string                          strLine;
      Regex  objRegExp;

      IWshRuntimeLibrary.IWshExec objExec = objShell.Exec(strCommand);
      tsStdOut = objExec.StdOut; //Reads the output from the command
      while (!tsStdOut.AtEndOfStream) 
      {
        strLine = tsStdOut.ReadLine();
        strLine = strLine.Trim();
        
        //test for Unknown Host
        objRegExp = new Regex("^Unknown", RegexOptions.IgnoreCase);
        if (objRegExp.IsMatch(strLine))
        {
          return false;
        }
        
        //DNS Succeeded, but box off-line
        objRegExp = new Regex("100% loss", RegexOptions.IgnoreCase);
        if (objRegExp.IsMatch(strLine))
        {
          return false;
        }

        //Got a reply
        objRegExp = new Regex("^Reply from", RegexOptions.IgnoreCase);
        if (objRegExp.IsMatch(strLine))
        {
          //Check for "Destination host unreachable."
          objRegExp = new Regex("Destination host unreachable", RegexOptions.IgnoreCase);
          if (objRegExp.IsMatch(strLine))
          {
            return false;
          } 
          else 
          {
            return true;
          }
        }
      }
      //Should never get here...
      return false;
    }
  }
}

The weird thing about the WshShell.Exec command is that you can see the window. No way that I know of to hide it.

In my opinion, not a big deal, but I'm hunting for a better solution.

Copyright © 2003, Christopher G. Lewis

GetFQDN

2003-09-19T10:34:00.000-05:00

I recently had the need to return the Fully Qualified Domain name for a Windows 2000 domain. It turns out that this is available via the RootDSE class's defaultNamingContext and rootDomainNamingContext properties.
Took me a little while to figure out where to find this information, but once I started looking into LDAP and the Active Directory, the solution was pretty simplistic.

'----------------------------------------+----------------------------------------
' GetFQDN.VBS - Script to get a Fully Qualified Domain Name for a W2K Domain
'
'  Copyright© 2003, Christopher G. Lewis - HTTP://www.ChristopherLewis.com
'
' Date   Name    Comment
' ------ ------- -----------------------------------------------------------------
' 030918 CGL     Created
'----------------------------------------+----------------------------------------
Option Explicit

Dim objRootDSE
Dim strNamingContext
Dim strDomain
Dim strQuery
Dim strFQDN

'Parse command line
If Wscript.arguments.Count = 0 Then
  strDomain = ""
Else
  strDomain = Wscript.arguments(0)
End If

'If command line is blank, process current domain
If strDomain = "" Then
  Wscript.echo "Getting FQDN current domain..."
  strQuery = "LDAP://RootDSE"
Else
  Wscript.echo "Getting FQDN for " & strDomain & "..."
  strQuery = "LDAP://" & strDomain & "/RootDSE"
End If

On Error Resume Next
'Open up a query to the RootDSE object.
'From the SDK: The RootDSE class provides information about the capabilities of an LDAP server.
Set objRootDSE = GetObject(strQuery)
If Err = 0 Then
  'Domain FQDN
  strNamingContext = objRootDSE.Get("defaultNamingContext")
  strFQDN = GetFQDNFromNamingContext(strNamingContext)
  Wscript.echo "Domain FQDN: " & strFQDN

  'Root Domain FQDN
  strNamingContext = objRootDSE.Get("rootDomainNamingContext")
  strFQDN = GetFQDNFromNamingContext(strNamingContext)
  Wscript.echo "Root Domain: " & strFQDN
Else
  Wscript.echo "Looks like Domain " & strDomain & " doesn't exist."
End If

'----------------------------------------+----------------------------------------
' GetFQDNFromNamingContext - Function to convert a Naming Context into a DNS name
'   Parms  : strNamingContext i.e. DC=Domain,DC=Company,DC=com
'   Returns: FQDN for strNamingContext ie.e Domain.Company.com
'
'   Notes  : LDAP allows for commas in strings, as long as they are escaped with
'            a \ character. (i.e. "CN=Lewis\, Chris") Sinces commas are not
'            allowed in domain names, there is no parsing for this is left out.
'            An implimentation of this would check to see if the last char was a
'            "\", and combine the two array elements.
'
' Date   Name    Comment
' ------ ------- -----------------------------------------------------------------
' 030919 CGL     Created
'----------------------------------------+----------------------------------------
Function GetFQDNFromNamingContext(strNamingContext)
  Dim aDomain
  Dim iCount
  Dim strTemp

  'Parse the NC by creating an array with the comma as an array boundry
  aDomain = Split(strNamingContext, ",")
  For iCount = 0 To UBound(aDomain)
    'Add a "." if needed
    If strTemp <> "" Then
      strTemp = strTemp & "."
    End If
    'Remove the "DC=" and add this item to the temp string
    strTemp = strTemp & Mid(aDomain(iCount), 4)
  Next
  'Return the FQDN
  GetFQDNFromNamingContext = strTemp
End Function

'----------------------------------------+----------------------------------------
' End of GetFQDN.VBS 
'----------------------------------------+----------------------------------------

Script to parse a URL

2003-09-17T10:52:00.000-05:00

Here's a little script that parses a URL and returns the Protocol, host and path. It uses Regular Expressions and the Match/SubMatch collections.

<?xml version="1.0" ?>
<package>
<comment>
'----------------------------------------+----------------------------------------
' ParseURL.wsf - Script to parse a URL in the form
'   prot://Host/path/file
'
'  Copyright© 2003, Christopher G. Lewis - HTTP://www.ChristopherLewis.com
'
' Date   Name    Comment
' ------ ------- -----------------------------------------------------------------
' 030916 CGL     Created
'----------------------------------------+----------------------------------------
</comment>
  <job>
    <runtime>
      <description>
        ParseURL.wsf (Version 1.0.00)
        Script to parse a URL in the form prot://Host/path/file
      </description>
      <!-- Command line arguments -->
      <unnamed
        name="URL"
        helpstring=""
        type="boolean"
        required="true"
      />
      <example>
        ParseURL.wsf http://slashdot.org
          - or -
        ParseURL.wsf ftp://ftp.sunsite.dk/projects/wget/windows/wget20030915b.zip
      </example>
    </runtime>
    <script language="VBScript">
<![CDATA[
Option Explicit

'Check for CScript
If Not IsCScript() Then
  WScript.Echo WScript.ScriptName & " must be run with CScript."
  WScript.Quit 1
End If

'Start main processing
Call Main

'----------------------------------------+----------------------------------------
' Main - Main sub
'
' Date   Name    Comment
' ------ ------- -----------------------------------------------------------------
' 030729 CGL     Created
'----------------------------------------+----------------------------------------
Sub Main()
  Dim strURL
  Dim objRegEx
  Dim colMatches
  Dim objMatch
  Dim strProtocol
  Dim strHost
  Dim strPath

  'Parse Command Line
  If WScript.Arguments.Unnamed.Count = 0 Then
    PrintSyntax()
    Wscript.Echo "  URL is required."
  Else
    strURL = Trim(WScript.Arguments.Unnamed(0))
    Wscript.Echo "Parsing URL: " & strURL
  End if

  'Parse URL
  Set objRegEx = New RegExp
  objRegEx.pattern = "^([\w]*://)([\w\-\.]*)([\w\.\-/]*)"
  objRegEx.Global = true
  If objRegEx.Test(strURL) Then
    Set colMatches = objRegEx.Execute(strURL)
    Set objMatch = colMatches(0)
    If objMatch.SubMatches.Count > 0 Then
      strProtocol = objMatch.SubMatches(0)
    End if
    If objMatch.SubMatches.Count > 1 Then
      strHost = objMatch.SubMatches(1)
    End if
    If objMatch.SubMatches.Count > 2 Then
      strPath = objMatch.SubMatches(2)
    End if
    Wscript.Echo "Prot: " & strProtocol
    Wscript.Echo "Host: " & strHost
    Wscript.Echo "Path: " & strPath
  Else
    wscript.echo "Input is an invalid URL"
  End if

End Sub

'----------------------------------------+----------------------------------------
' IsCscript - Checks CScript vs. WScript
'
' Date   Name    Comment
' ------ ------- -----------------------------------------------------------------
' 020507 CGL     Created
'----------------------------------------+----------------------------------------
Function IsCScript()
  Dim objRegExp
  Set objRegExp = New RegExp
  objRegExp.IgnoreCase = True
  objRegExp.Pattern = "cscript.exe$"
  IsCScript = objRegExp.Test(WScript.FullName)
  Set objRegExp = Nothing
End Function

'----------------------------------------+----------------------------------------
' PrintSyntax - PrintSyntax
'
' Date   Name    Comment
' ------ ------- -----------------------------------------------------------------
' 030606 CGL     Created
'----------------------------------------+----------------------------------------
Function PrintSyntax()
  WScript.Arguments.ShowUsage()
End Function

'----------------------------------------+----------------------------------------
' End of ParseURL.wsf
'----------------------------------------+----------------------------------------
]]>
    </script>
  </job>
</package>

Blogger Creation

2003-09-11T10:02:00.000-05:00